Задача. В УТ есть документ который должен выгружаться в БП в док. Операция. Как в конвертации 2.1 сделать ПКС для Субконто? Т.е. у меня в УТ в документе есть например реквизиты "Контрагент" и "Договор", надо чтобы при выгрузке они легли как 1 и 2 субконто в Кт.

Для начала сСнять метаданные приемника с флажком "Движения", дальше в КД 2 готовишь ПКГС нужной структуры

Альтернативный вариант - передавать необходимые для формирования движений значения через ПКС-параметры, а в обработчиках приемника уже формировать движения

(1) Да, понял. Все получилось. Спасибо!

На всякий случай для народа код в ПКГС "Хозрасчетый"

ДатаДвижений = Источник.Дата;

КоллекцияОбъектов = Новый ТаблицаЗначений;

КоллекцияОбъектов.Колонки.Добавить("Активность" , Новый ОписаниеТипов("Булево"));
КоллекцияОбъектов.Колонки.Добавить("Период"     , Новый ОписаниеТипов("Дата"));
КоллекцияОбъектов.Колонки.Добавить("СчетДт"     , Новый ОписаниеТипов("ПланСчетовСсылка.Хозрасчетный"));
КоллекцияОбъектов.Колонки.Добавить("СубконтоДт");
КоллекцияОбъектов.Колонки.Добавить("СчетКт"     , Новый ОписаниеТипов("ПланСчетовСсылка.Хозрасчетный"));
КоллекцияОбъектов.Колонки.Добавить("СубконтоКт");
КоллекцияОбъектов.Колонки.Добавить("Организация", Новый ОписаниеТипов("СправочникСсылка.Организации"));
КоллекцияОбъектов.Колонки.Добавить("Сумма"      , Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(15,2)));
КоллекцияОбъектов.Колонки.Добавить("СуммаНУДт"  , Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(15,2)));
КоллекцияОбъектов.Колонки.Добавить("СуммаНУКт"  , Новый ОписаниеТипов("Число", Новый КвалификаторыЧисла(15,2)));
КоллекцияОбъектов.Колонки.Добавить("Содержание" , Новый ОписаниеТипов("Строка", Новый КвалификаторыСтроки(150)));

Запрос = Новый Запрос;

Запрос.УстановитьПараметр("Ссылка", Источник.Ссылка);

Запрос.Текст =
"ВЫБРАТЬ
|    Д_ОтчетТаможенногоПредставителяПлатежи.НомерЧека,
|    Д_ОтчетТаможенногоПредставителяПлатежи.ДатаЧека,
|    Д_ОтчетТаможенногоПредставителяПлатежи.Сумма,
|    Д_ОтчетТаможенногоПредставителяПлатежи.ДокументОплаты,
|    Д_ОтчетТаможенногоПредставителяПлатежи.Ссылка.Организация КАК Организация,
|    Д_ОтчетТаможенногоПредставителяПлатежи.Ссылка.Контрагент КАК Контрагент,
|    Д_ОтчетТаможенногоПредставителяПлатежи.Ссылка.ДоговорКонтрагента КАК ДоговорКонтрагента,
|    Д_ОтчетТаможенногоПредставителяПлатежи.Ссылка.ФТС КАК ФТС,
|    Д_ОтчетТаможенногоПредставителяПлатежи.Ссылка.ДоговорФТС КАК ДоговорФТС
|ИЗ
|    Документ.Д_ОтчетТаможенногоПредставителя.Платежи КАК Д_ОтчетТаможенногоПредставителяПлатежи
|ГДЕ
|    Д_ОтчетТаможенногоПредставителяПлатежи.Ссылка = &Ссылка
|
|УПОРЯДОЧИТЬ ПО
|    Д_ОтчетТаможенногоПредставителяПлатежи.НомерСтроки";

Выборка = Запрос.Выполнить().Выбрать();

Пока Выборка.Следующий() Цикл
    
    СубконтоДт = Новый Соответствие;

    СубконтоДт.Вставить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Контрагенты                    , Выборка.Контрагент);
    СубконтоДт.Вставить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Договоры                       , Выборка.ДоговорКонтрагента);
    СубконтоДт.Вставить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.ДокументыРасчетовСКонтрагентами, Выборка.ДокументОплаты);
    
    СубконтоКт = Новый Соответствие;

    СубконтоКт.Вставить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Контрагенты                    , Выборка.ФТС);
    СубконтоКт.Вставить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.Договоры                       , Выборка.ДоговорФТС);
    СубконтоКт.Вставить(ПланыВидовХарактеристик.ВидыСубконтоХозрасчетные.ДокументыРасчетовСКонтрагентами, Неопределено);
    
    НоваяСтрока = КоллекцияОбъектов.Добавить();
    
    НоваяСтрока.Активность  = Истина;        
    НоваяСтрока.Период      = ДатаДвижений;        
    НоваяСтрока.СчетДт      = ПланыСчетов.Хозрасчетный.РасчетыСПрочимиПоставщикамиИПодрядчиками;        
    НоваяСтрока.СубконтоДт  = СубконтоДт;
    НоваяСтрока.СчетКт      = ПланыСчетов.Хозрасчетный.РасчетыСПрочимиПоставщикамиИПодрядчиками;        
    НоваяСтрока.СубконтоКт  = СубконтоКт;
    НоваяСтрока.Организация = Выборка.Организация;
    НоваяСтрока.Сумма       = Выборка.Сумма;
    НоваяСтрока.СуммаНУДт   = Выборка.Сумма;
    НоваяСтрока.СуммаНУКт   = Выборка.Сумма;    
    НоваяСтрока.Содержание  = "чек " + Выборка.НомерЧека + " от " + Формат(Выборка.ДатаЧека, "ДФ=dd.MM.yyyy");
    
КонецЦикла;