На обычных формах было при ВыводеСтроки, а в УФ, как программно реализовать?

использовать условное оформление

(1) Условное оформление, которое вызывается из свойств формы не катит, нужно именно программно. Кода под рукой нет?

(2) кто тебе мешает задать условное оформление программно? религия?

(3) Угу. Вот сижу разрешения жду. Не понимая того, как задается УО для ТЧ в доке. И код не могу нагуглить.

Наверняка на сайте ИТС есть Примеры ИТС.

&НаСервере
Процедура УстановитьУсловноеОформление()
    
    УсловноеОформление.Элементы.Очистить();

    Элемент = УсловноеОформление.Элементы.Добавить();

    ПолеЭлемента = Элемент.Поля.Элементы.Добавить();
    ПолеЭлемента.Поле = Новый ПолеКомпоновкиДанных(Элементы.ТоварыКонтрагент.Имя);

    ОтборЭлемента = Элемент.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    ОтборЭлемента.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Объект.Товары.Контрагент");
    ОтборЭлемента.ВидСравнения = ВидСравненияКомпоновкиДанных.НеЗаполнено;
    
    Элемент.Оформление.УстановитьЗначениеПараметра("Текст", НСтр("ru = '<указан в основных реквизитах>'"));
    Элемент.Оформление.УстановитьЗначениеПараметра("ОтметкаНезаполненного", Ложь);

    Элемент = УсловноеОформление.Элементы.Добавить();

    ПолеЭлемента = Элемент.Поля.Элементы.Добавить();
    ПолеЭлемента.Поле = Новый ПолеКомпоновкиДанных(Элементы.ТоварыЗаявкаНаСклад.Имя);

    ОтборЭлемента = Элемент.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    ОтборЭлемента.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Объект.Товары.Контрагент");
    ОтборЭлемента.ВидСравнения = ВидСравненияКомпоновкиДанных.НеЗаполнено;

    Элемент.Оформление.УстановитьЗначениеПараметра("ТолькоПросмотр", Истина);
    
КонецПроцедуры

примеров масса в УТ11

(6) Спс.

(4) интересно, что жамкнув на кнопочку "я" в правом углу, получаешь вполне себе ссылки на мисту, где есть подобный код.