Создал общий модуль "работа с диалогами"
Хотел туда всунуть процедурку установки заголовка формы. Формы управляемые.
Создал модуль, всунул туда это:

Процедура УстановитьЗаголовокФормыДокумента(СтрокаВидаОперации = "", ДокументОбъект, ФормаДокумента) Экспорт

   ФормаДокумента.АвтоЗаголовок = Ложь;
   
   Если ПустаяСтрока(СтрокаВидаОперации) Тогда
       Заголовок = ДокументОбъект.Ссылка.Метаданные().Синоним + ": ";
   Иначе
       Заголовок = ДокументОбъект.Ссылка.Метаданные().Синоним + ": " + СтрокаВидаОперации + ". ";
   КонецЕсли;
       
   Если ДокументОбъект.ЭтоНовый() Тогда  
       Заголовок = Заголовок + "Новый";
   Иначе
       Если ДокументОбъект.Проведен Тогда
           Заголовок = Заголовок + "Проведен";
       ИначеЕсли ДокументОбъект.Ссылка.Метаданные().Проведение = Метаданные.СвойстваОбъектов.Проведение.Разрешить Тогда
           Заголовок = Заголовок + "Не проведен";
       Иначе
           Заголовок = Заголовок + "Записан";
       КонецЕсли;
   КонецЕсли;
   
   ФормаДокумента.Заголовок = Заголовок;

КонецПроцедуры

Скопипастено из типовой бухии, слегка кое что добавил ("Ссылка" после "ДокументОбъект") дабы отрабатывало без ошибок.

Но одного не могу понять.
ДокументОбъект.ЭтоНовый() - метод не найден.
"ДокументОбъект" действительно Объект, СП говорит, что для Объекта Документа такой метод доступен, почему тогда при работе в режиме предприятия метод не доступен?
Что то не сделал в свойствах общего модуля?

какого типа ДокументОбъект?

"ДокументОбъект" действительно Объект,  - скрин можно?

Я понял свою ошибку...
Передаю "Объект" из модуля формы документа,а на приеме "ДанныеФормыСтруктура"
Следовательно из формы документа сам по себе "Объект" оным не является.

Хочу уточнить, "Объект" является объектом только в модуле документа или через Объект.Ссылка.ПолучитьОбъект() В остальных случаях?

пиши так:

НастоящийОбъект = Объект;

и его уже передавай

Объект - это, блин, имя переменной

РеквизитФормыВЗначение()

а нафига там .Ссылка?

(7) структура не имеет метода "Метаданные()"
(4) Так и делал же...  Из модуля формы:


РаботаСДиалогами.УстановитьЗаголовокФормыДокумента(Строка(Объект.ВидОперации), Объект, ЭтаФорма);


Сейчас все в порядке и все отрабатывает как надо:


Процедура УстановитьЗаголовокФормыДокумента(СтрокаВидаОперации = "", ДокументОбъект, ФормаДокумента) Экспорт

   ФормаДокумента.АвтоЗаголовок = Ложь;
   
   Если ПустаяСтрока(СтрокаВидаОперации) Тогда
       Заголовок = ДокументОбъект.Ссылка.Метаданные().Синоним + ": ";
   Иначе
       Заголовок = ДокументОбъект.Ссылка.Метаданные().Синоним + ": " + СтрокаВидаОперации + ". ";
   КонецЕсли;
       
   Если ДокументОбъект.Ссылка.ПолучитьОбъект().ЭтоНовый() Тогда  
       Заголовок = Заголовок + "Новый";
   Иначе
       Если ДокументОбъект.Проведен Тогда
           Заголовок = Заголовок + "Проведен";
       ИначеЕсли ДокументОбъект.Ссылка.Метаданные().Проведение = Метаданные.СвойстваОбъектов.Проведение.Разрешить Тогда
           Заголовок = Заголовок + "Не проведен";
       Иначе
           Заголовок = Заголовок + "Записан";
       КонецЕсли;
   КонецЕсли;
   
   ФормаДокумента.Заголовок = Заголовок;

КонецПроцедуры

(8) читай (6)

Если ДокументОбъект.Ссылка.ПолучитьОбъект().ЭтоНовый() Тогда  
       Заголовок = Заголовок + "Новый";
   Иначе


... и это работает?
не - по другому, и ты думаешь что это работает?

(9) нет такого метода

(11) в управляемой форме на сервере надо сделать МойОбъект = РеквизитФормыВЗначение и дальше его передавать в метод.
Если там что-то меняется - то надо сделать ЗначениеВРЕквизитФормы

(10) неа.. не работает ((

Все, поправил вызов так:

   ДокументОбъект = ДанныеФормыВЗначение(Объект, Тип("ДокументОбъект."+Объект.Ссылка.Метаданные().Имя));
   РаботаСДиалогами.УстановитьЗаголовокФормыДокумента(Строка(Объект.ВидОперации), ДокументОбъект, ЭтаФорма);


Процедуру в общем модуле так:

Процедура УстановитьЗаголовокФормыДокумента(СтрокаВидаОперации = "", ДокументОбъект, ФормаДокумента) Экспорт

   ФормаДокумента.АвтоЗаголовок = Ложь;
   
   Если ПустаяСтрока(СтрокаВидаОперации) Тогда
       Заголовок = ДокументОбъект.Метаданные().Синоним + ": ";
   Иначе
       Заголовок = ДокументОбъект.Метаданные().Синоним + ": " + СтрокаВидаОперации + ". ";
   КонецЕсли;
       
   Если ДокументОбъект.ЭтоНовый() Тогда  
       Заголовок = Заголовок + "Новый";
   Иначе
       Если ДокументОбъект.Проведен Тогда
           Заголовок = Заголовок + "Проведен";
       ИначеЕсли ДокументОбъект.Метаданные().Проведение = Метаданные.СвойстваОбъектов.Проведение.Разрешить Тогда
           Заголовок = Заголовок + "Не проведен";
       Иначе
           Заголовок = Заголовок + "Записан";
       КонецЕсли;
   КонецЕсли;
   
   ФормаДокумента.Заголовок = Заголовок;

КонецПроцедуры


Теперь ВСЕ отрабатывает верно.
Спасибо ребяты)))

(14) убери тип, он в этом случае необязателен

(15) уверены?
СП говорит, что в любом случае обязателен