Пытаюсь получить для номенклатуры серию с наивысшей срок годности по оси времени. Сейчас результат выдает к одной номенклатуры из втОстатки все серии.
ВЫБРАТЬ
    ТоварыВНТТОстатки.Номенклатура,
    СУММА(ТоварыВНТТОстатки.КоличествоОстаток) КАК КоличествоОстаток
ПОМЕСТИТЬ втОстатки
ИЗ
    РегистрНакопления.ТоварыВНТТ.Остатки(
            &Граница,
            Склад = &Склад
                И ВЫБОР
                    КОГДА &ФлажокТолькоНоменклатураУчетПоСериям
                        ТОГДА Номенклатура.ВестиУчетПоСериям = ИСТИНА
                    ИНАЧЕ ИСТИНА
                КОНЕЦ) КАК ТоварыВНТТОстатки

СГРУППИРОВАТЬ ПО
    ТоварыВНТТОстатки.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СерииНоменклатуры.Ссылка КАК СерияНоменклатуры,
    МАКСИМУМ(СерииНоменклатуры.СрокГодности) КАК СрокГодности,
    СерииНоменклатуры.Владелец
ПОМЕСТИТЬ втМаксСерия
ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры
ГДЕ
    СерииНоменклатуры.Владелец В
            (ВЫБРАТЬ
                втОстатки.Номенклатура
            ИЗ
                втОстатки КАК втОстатки)

СГРУППИРОВАТЬ ПО
    СерииНоменклатуры.Ссылка,
    СерииНоменклатуры.Владелец
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    втОстатки.Номенклатура,
    СУММА(втОстатки.КоличествоОстаток) КАК КоличествоОстаток,
    втМаксСерия.СерияНоменклатуры
ИЗ
    втОстатки КАК втОстатки
        ЛЕВОЕ СОЕДИНЕНИЕ втМаксСерия КАК втМаксСерия
        ПО втОстатки.Номенклатура = втМаксСерия.Владелец

СГРУППИРОВАТЬ ПО
    втМаксСерия.СерияНоменклатуры,
    втОстатки.Номенклатура

подозреваю что из за группировки по Владельцу и Ссылки во втором запросе

Пытаюсь получить для номенклатуры серию с наивысшей срок годности по оси времени. Сейчас результат выдает к одной номенклатуры из втОстатки все серии.

ТАк вы ж группируете по серии и номенклатуре Оо.
Сгруппируйте по номенклатуре, получите макс срок годности. Потом к нему привяжите серию. А потом всё это дело к остаткам.

(1) Правильно подозреваешь.
Выбери просто максимальный срок годности.
Потом - соедини с сериями по владельцу и срокгодности = максимальный срок годности.

не получается

ВЫБРАТЬ
    ТоварыВНТТОстатки.Номенклатура,
    СУММА(ТоварыВНТТОстатки.КоличествоОстаток) КАК КоличествоОстаток
ПОМЕСТИТЬ втОстатки
ИЗ
    РегистрНакопления.ТоварыВНТТ.Остатки(
            &Граница,
            Склад = &Склад
                И ВЫБОР
                    КОГДА &ФлажокТолькоНоменклатураУчетПоСериям
                        ТОГДА Номенклатура.ВестиУчетПоСериям = ИСТИНА
                    ИНАЧЕ ИСТИНА
                КОНЕЦ) КАК ТоварыВНТТОстатки

СГРУППИРОВАТЬ ПО
    ТоварыВНТТОстатки.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    КОЛИЧЕСТВО(РАЗЛИЧНЫЕ СерииНоменклатуры.СрокГодности) КАК СрокГодности,
    СерииНоменклатуры.Ссылка КАК СерияНоменклатуры
ПОМЕСТИТЬ вт1
ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры
ГДЕ
    СерииНоменклатуры.Владелец В
            (ВЫБРАТЬ
                втОстатки.Номенклатура
            ИЗ
                втОстатки КАК втОстатки)

СГРУППИРОВАТЬ ПО
    СерииНоменклатуры.Ссылка
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    СерииНоменклатуры.Ссылка КАК СерияНоменклатуры
ПОМЕСТИТЬ вт2
ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры
        ЛЕВОЕ СОЕДИНЕНИЕ вт1 КАК вт1
        ПО СерииНоменклатуры.Ссылка = вт1.СерияНоменклатуры
            И СерииНоменклатуры.СрокГодности = вт1.СрокГодности
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    втОстатки.Номенклатура,
    вт2.СерияНоменклатуры,
    втОстатки.КоличествоОстаток
ИЗ
    втОстатки КАК втОстатки
        ЛЕВОЕ СОЕДИНЕНИЕ вт2 КАК вт2
        ПО втОстатки.Номенклатура = вт2.СерияНоменклатуры.Владелец

Тут у тебя совсем не срок годности

КОЛИЧЕСТВО(РАЗЛИЧНЫЕ СерииНоменклатуры.СрокГодности) КАК СрокГодности,

(5) да я заметил исправляю

(4)
ВЫБРАТЬ
    СерииНоменклатуры.Владелец КАК Номенклатура
,   МАКСИМУМ(СерииНоменклатуры.СрокГодности) КАК МаксСрокГодности
ПОМЕСТИТЬ МаксСрокиГодности
ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры
СГРУППИРОВАТЬ ПО
    СерииНоменклатуры.Владелец;
ВЫБРАТЬ
    СерииНоменклатуры.Ссылка
ПОМЕСТИТЬ СерииСМаксСрокомГодности
ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры
    СОЕДИНЕНИЕ МаксСрокиГодности
        ПО СерииНоменклатуры.СрокГодности = МаксСрокиГодности.МаксСрокГодности
        М СерииНоменклатуры.Владелец = МаксСрокиГодности.Номенклатура

ВЫБРАТЬ
    ТоварыВНТТОстатки.Номенклатура,
    СУММА(ТоварыВНТТОстатки.КоличествоОстаток) КАК КоличествоОстаток
ПОМЕСТИТЬ втОстатки
ИЗ
    РегистрНакопления.ТоварыВНТТ.Остатки(
            &Граница,
            Склад = &Склад
                И ВЫБОР
                    КОГДА &ФлажокТолькоНоменклатураУчетПоСериям
                        ТОГДА Номенклатура.ВестиУчетПоСериям = ИСТИНА
                    ИНАЧЕ ИСТИНА
                КОНЕЦ) КАК ТоварыВНТТОстатки

СГРУППИРОВАТЬ ПО
    ТоварыВНТТОстатки.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СерииНоменклатуры.Владелец,
    МАКСИМУМ(СерииНоменклатуры.СрокГодности) КАК СрокГодности
ПОМЕСТИТЬ втМаксСрокГодности
ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры
ГДЕ
    СерииНоменклатуры.Владелец В
            (ВЫБРАТЬ
                втОстатки.Номенклатура
            ИЗ
                втОстатки КАК втОстатки)

СГРУППИРОВАТЬ ПО
    СерииНоменклатуры.Владелец
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СерииНоменклатуры.Ссылка КАК СерияНоменклатуры
ПОМЕСТИТЬ втСерия
ИЗ
    втМаксСрокГодности КАК втМаксСрокГодности
        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.СерииНоменклатуры КАК СерииНоменклатуры
        ПО втМаксСрокГодности.Владелец = СерииНоменклатуры.Владелец
            И втМаксСрокГодности.СрокГодности = СерииНоменклатуры.СрокГодности
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    втОстатки.Номенклатура,
    втСерия.СерияНоменклатуры,
    СУММА(втОстатки.КоличествоОстаток) КАК КоличествоОстаток
ИЗ
    втОстатки КАК втОстатки,
    втСерия КАК втСерия

СГРУППИРОВАТЬ ПО
    втСерия.СерияНоменклатуры,
    втОстатки.Номенклатура

эх близко был блин.

спасибо (7)

дублируется номенклатура.

ВЫБРАТЬ
    ТоварыВНТТОстатки.Номенклатура,
    СУММА(ТоварыВНТТОстатки.КоличествоОстаток) КАК КоличествоОстаток
ПОМЕСТИТЬ втОстатки
ИЗ
    РегистрНакопления.ТоварыВНТТ.Остатки(
            &Граница,
            Склад = &Склад
                И ВЫБОР
                    КОГДА &ФлажокТолькоНоменклатураУчетПоСериям
                        ТОГДА Номенклатура.ВестиУчетПоСериям = ИСТИНА
                    ИНАЧЕ ИСТИНА
                КОНЕЦ) КАК ТоварыВНТТОстатки

СГРУППИРОВАТЬ ПО
    ТоварыВНТТОстатки.Номенклатура
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СерииНоменклатуры.Владелец,
    МАКСИМУМ(СерииНоменклатуры.СрокГодности) КАК СрокГодности
ПОМЕСТИТЬ втМаксСрокГодности
ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры

СГРУППИРОВАТЬ ПО
    СерииНоменклатуры.Владелец
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    СерииНоменклатуры.Ссылка КАК СерияНоменклатуры,
    СерииНоменклатуры.Владелец
ПОМЕСТИТЬ втСерииСМаксСрокомГодности
ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры
        ЛЕВОЕ СОЕДИНЕНИЕ втМаксСрокГодности КАК втМаксСрокГодности
        ПО СерииНоменклатуры.Владелец = втМаксСрокГодности.Владелец
            И СерииНоменклатуры.СрокГодности = втМаксСрокГодности.СрокГодности
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    втОстатки.Номенклатура,
    втСерииСМаксСрокомГодности.СерияНоменклатуры,
    СУММА(втОстатки.КоличествоОстаток) КАК КоличествоОстаток
ИЗ
    втОстатки КАК втОстатки
        ЛЕВОЕ СОЕДИНЕНИЕ втСерииСМаксСрокомГодности КАК втСерииСМаксСрокомГодности
        ПО втОстатки.Номенклатура = втСерииСМаксСрокомГодности.СерияНоменклатуры.Владелец

СГРУППИРОВАТЬ ПО
    втОстатки.Номенклатура,
    втСерииСМаксСрокомГодности.СерияНоменклатуры

УПОРЯДОЧИТЬ ПО
    втОстатки.Номенклатура.Наименование

может быть из за того что не везде поле СрокГодности заполнен

(12) Либо у одной номенклатуры есть несколько серий с одним и тем же сроком годности. Но тут уж надо определиться - какую серию (по каким признакам) в таком случае выбирать.

(12) Вот здесь

ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры
        ЛЕВОЕ СОЕДИНЕНИЕ втМаксСрокГодности КАК втМаксСрокГодности
        ПО СерииНоменклатуры.Владелец = втМаксСрокГодности.Владелец
            И СерииНоменклатуры.СрокГодности = втМаксСрокГодности.СрокГодности


вместо левого, внутреннее соединение плюс (13).

(14) Как вариант

ВЫБРАТЬ
    Максимум(СерииНоменклатуры.Ссылка) КАК СерияНоменклатуры,
    СерииНоменклатуры.Владелец
ПОМЕСТИТЬ втСерииСМаксСрокомГодности
ИЗ
    Справочник.СерииНоменклатуры КАК СерииНоменклатуры
        Внутреннее СОЕДИНЕНИЕ втМаксСрокГодности КАК втМаксСрокГодности
        ПО СерииНоменклатуры.Владелец = втМаксСрокГодности.Владелец
            И СерииНоменклатуры.СрокГодности = втМаксСрокГодности.СрокГодности
Сгруппировать ПО СерииНоменклатуры.Владелец
;